home *** CD-ROM | disk | FTP | other *** search
/ Sprite 1984 - 1993 / Sprite 1984 - 1993.iso / src / boot / netBoot / sun3.md / map.s < prev    next >
Encoding:
Text File  |  1990-08-14  |  3.1 KB  |  96 lines
  1. |     map.s 1.2 88/02/08 Copyright (c) 1985 by Sun Microsystems, Inc.
  2. |
  3. | /*
  4. |  * Memory Mapping and Paging on the Sun 3
  5. |  */
  6. | 
  7. | /*
  8. |  * Mapping registers are accessed thru the  movs  instruction in the Sun-3.
  9. |  *
  10. |  * The following subroutines accept any address in the mappable range
  11. |  * (256 megs).  They access the map for the current context register.  They
  12. |  * assume that currently we are running in supervisor state.
  13. |  */ 
  14. | 
  15. /* 
  16.  * These constants are fixed by the hardware, 
  17.  * so don't feel too bad that I redefined them here
  18.  */
  19. #define    FC_MAP        3        /* space for MMU ops */
  20. #define    NUMPMEGS    256        /* number of Pmegs */
  21. #define    PMAPOFF        0x10000000    /* offset for page map */
  22. #define    SMAPOFF        0x20000000    /* offset for segment map */
  23. #define    MAPADDRMASK    0x0FFFE000    /* translatable bits */
  24. #define    PME_INVALID    0        /* invalid page */
  25.  
  26.     .text
  27.  
  28.     .globl    _setpgmap
  29. _setpgmap:
  30.     movl    sp@(4),d0    | Get access address
  31.     andl    #MAPADDRMASK,d0    | Mask out irrelevant bits
  32.     addl    #PMAPOFF,d0    | Offset to page maps
  33.     movl    d0,a0
  34.     lea    FC_MAP,a1    | Get function code in a reg
  35. | The following code can be used to verify that the only page
  36. | table entries written to the Invalid Pmeg are invalid pages, since the 
  37. | consequences of writing valid entries here are somewhat spectacular.
  38.     movc    sfc,d0        | Save source function code
  39.     movc    a1,sfc        | Set source function code, too.
  40.     addl    #SMAPOFF-PMAPOFF,a0    | Offset to segment map
  41.     movsb    a0@,d1        | Get segment map entry number
  42.     subl    #SMAPOFF-PMAPOFF,a0    | Offset back to page map
  43.     movc    d0,sfc        | Restore source function code
  44. | If debug code is removed, next line must remain!
  45.     movl    sp@(8),d0    | Get page map entry to write
  46. | More debug code
  47. #if NUMPMEGS != 256
  48.     andb    #NUMPMEGS-1,d1    | Top bit ignored in 128-pmeg version
  49. #endif
  50.     cmpb    #NUMPMEGS-1,d1    | Are we writing in the Invalid Pmeg?
  51.     jne    good        | Nope, go on.
  52.     cmpl    #PME_INVALID,d0    | Writing the Invalid Page Map Entry?
  53.     jeq    good        | Yes, it's ok.
  54.     bras    .-1        | Fault out, this is nasty thing to do.
  55. good:
  56.     movc    dfc,d1        | Save dest function code
  57.     movc    a1,dfc        | Set destination function code
  58.     movsl    d0,a0@        | Write page map entry
  59.     movc    d1,dfc        | Restore dest function code
  60.     rts            | done
  61.  
  62. |
  63. | Read the page map entry for the given address v
  64. | and return it in a form suitable for software use.
  65. |
  66. | long
  67. | getpgmap(v)
  68. | caddr_t v;
  69.     .globl    _getpgmap
  70. _getpgmap:
  71.     movl    sp@(4),d0        | get access address
  72.     andl    #MAPADDRMASK,d0        | clear extraneous bits
  73.     orl    #PMAPOFF,d0        | set to page map base offset
  74.     lea    FC_MAP,a1        | Get function code in a reg
  75.     movc    sfc,d1            | Save source function code
  76.     movc    a1,sfc            | Set source function code, too.
  77.     movl    d0,a0
  78.     movsl    a0@,d0            | read page map entry
  79.                     | no mods needed to make pte from pme
  80.     movc    d1,sfc            | restore function code
  81.     rts                | done
  82.  
  83.     .globl    _setsegmap
  84. _setsegmap:
  85.     movl    sp@(4),d0    | Get access address
  86.     andl    #MAPADDRMASK,d0    | Mask out irrelevant bits
  87.     addl    #SMAPOFF,d0    | Bump to segment map offset
  88.     movl    d0,a0
  89.     movl    sp@(8),d0    | Get seg map entry to write
  90.     movc    dfc,d1        | Save dest function code
  91.     lea    FC_MAP,a1    | Get function code in a reg
  92.     movc    a1,dfc        | Set destination function code
  93.     movsb    d0,a0@        | Write segment map entry
  94.     movc    d1,dfc        | Restore dest function code
  95.     rts            | done
  96.